Morris' Blog 我在摸索我存在的意義、生命的意義、內涵及價值。 沒有真正神手般的厲害，套用模式是大部分的情況。 沒那麼厲害的我存在的意義為何，襯托出神的存在？ 有時候不能怪別人不給我機會，我已經開始省思， 為什麼我沒有給別人機會的原因，而是全要靠別人。 有時候我認為我與眾不同，那是因為我做不到很多人能辦到的事情。 我聽不到、玩不起來、說得不夠明瞭、理解得不夠多， 我缺少的語文能力，就是一切一切無能的判定。 為此，我不曉得能做些對別人有幫助的事情。 我知道我自己是個不服輸的性格，但現在我不得不認輸。 我沒有能力，因此我必須認輸。 我到底來這世界作什麼？處處充滿不確定性， 而我總是無法出類拔萃，想當個一般人似乎也回不了頭了。 越強大的挑戰需要越強力的支持，而我的支持是什麼？ 最近嘗試與人談話，但都是失敗的結局，沒人能接受， 不需要言語，不需要溝通，一切所想都表達不出來。

49愛的鼓勵 6訂閱站台

作業內容：

作業規定：
宣告變數 Declare

BStr0 db ?

BStr1 db ?

BStr2 db ?

BStr3 db ?

BStr4 db ?

BStr5 db ?

BStr6 db ?

  BStr7 db ?

CStr0 db 8 dup (?)

CStr1 db 8 dup (?)

CStr2 db 8 dup (?)

CStr3 db 8 dup (?)

CStr4 db 8 dup (?)

CStr5 db 8 dup (?)

CStr6 db 8 dup (?)

CStr7 db 8 dup (?)

※紅色部分不能變動

心得

這次作業多了一些 call function 的指令，而同時練習到自己寫函數去呼叫，由於暫存器就那麼幾個，
因此必須叫函數前，把參數傳入到特定的暫存器，假如被呼叫的函數內部會修改某些暫存器，
為了不影響原本呼叫的函數繼續執行，要先將這些變數先丟入堆疊中，而在被呼叫函數結束後被複製回來。

切記在回傳一定要打上 ret，不然會發生無法預期的錯誤 ASM 並沒有像 MIPS 指令複雜，
不用自己操作 eps 的值。

由於不可能對於每個變數都呼叫一次轉換，程式可能簡單好懂，但過於累贅，因此採用 BYTE address 
方式去讀取，只抓第一個變數的位址，然後依序累加，同理輸出的位址。

程式碼說明

程式分成三個部分去處理

第一部分：

單處理一個8 bits 的數字轉換成 ASCII，從最高位依序納入低位元位址。

第二部分：

給定一個 address，將接續的 64 bytes，以8*8 的矩陣方式印出，以 ASCII 顯示。

第三部分：

分別依序呼叫八個變數，將這八個變數的值存入給定的位址。

程式碼：


TITLE

INCLUDE Irvine32.inc
.data
BStr0 db 01111110b
BStr1 db 10000001b
BStr2 db 10100101b
BStr3 db 10000001b
BStr4 db 10100101b
BStr5 db 10111101b
BStr6 db 10000001b
BStr7 db 01111110b
CStr0 db 8 dup(?)
CStr1 db 8 dup(?)
CStr2 db 8 dup(?)
CStr3 db 8 dup(?)
CStr4 db 8 dup(?)
CStr5 db 8 dup(?)
CStr6 db 8 dup(?)
CStr7 db 8 dup(?)
.code
convertPattern PROC
; al = binary integer, esi pointer to buffer
    push ecx
    push esi
   
    mov ecx, 8             ; number of bits in AL
L1: shl al, 1              ; shift high bit into carry flag
    mov BYTE PTR[esi], ' ' ; choose ' ' as default output
    jnc L2                 ; if no Carry, jump L2
    mov BYTE PTR[esi], '*' ; else move '*' to buffer
L2: inc esi                ; next buffer position
    loop L1                ; shift another bit to left
   
    pop esi
    pop ecx
    ret
convertPattern ENDP

printResult PROC
; esi pointer to buffer, print[8][8]
    push ecx
    push esi
   
    mov ecx, 8            ; number of rows
L1: push ecx
    mov ecx, 8            ; number of column
L2: mov al, BYTE PTR[esi] ; move buffer to AL
    inc esi               ; next buffer position
    call WriteChar        ; print AL(ASCII)
    loop L2               ; next column
   
    call Crlf             ; print '\n'
    pop ecx
    loop L1               ; next row
   
    pop esi
    pop ecx
    ret
printResult ENDP

start PROC
    mov ebx, 0            ; BStr[ebx]
    mov ecx, 8            ; run BStr[0-7]
    mov esi, OFFSET CStr0 ; move buffer position to esi
L1: mov al, BStr0[ebx]    ; move byte BStr[ebx] to AL
    call convertPattern   ; convert bit pattern
    add esi, SIZEOF CStr0 ; next buffer position
    add ebx, SIZEOF BStr0 ; next convert byte
    loop L1
    mov esi, OFFSET CStr0 ; output
    call printResult
    call WaitMsg
    invoke ExitProcess, 0
start ENDP;
end start;